PROC showmen%:
   ...
   mCARD "Kunden","Neu",%n,"Ändern",%a,"Suchen",%s,"Gehe zu",%g,"Löschen",%l
   ...
ENDP

PROC DoMenu:(k%)
   ...
   menuops$="enagls"
   ...
ENDP

PROC startup:
   global filenam$(130), basenam$(10), name$(20), tel$(20)
   FONT 268436068,1
   inifile:
   main:
endp

proc inifile:
   basenam$="\MEINE_DB"
   trap mkdir(basenam$)
   filenam$ = basenam$ + "\" + "KUNDEN.ODB"
   if not exist(filenam$)
      trap create filenam$, A, name$, tel$
   else
      trap open filenam$, A, name$, tel$
   endif
   showknd:
endp

proc main:
   global taste%, mod%
   do
      taste%=get : mod%=KMOD
      if taste%=290
         showmen%:
      elseif (mod% AND 4)
         taste%=taste% + 96
         DoMenu:(taste%)
      elseif (taste% AND $FF00)
         if taste%=259
            rollen:(taste%)
         elseif taste%=258
            rollen:(taste%)
         endif
      endif
   until 0
endp

proc showmen%:
   local keycode%
   minit
   mcard "Datei","Beenden",%e
   mCARD "Kunden","Neu",%n,"Ändern",%a,"Suchen",%s,"Gehe zu",%g,"Löschen",%l
   keycode% = menu
   domenu:(keycode%)
endp

proc domenu:(k%)
   local k$(1)
   local menuops$(10)
rem   menuops$="enal"
   menuops$="enagls"
   k$=chr$(k% and $FF)
   if loc(menuops$,k$)
      @%("wahl"+k$):
   endif
endp

proc wahln%:
   local erg%
   use a
   delkndva:
   erg% = ediknd%:("Kunden anlegen")
   if erg% = 0
      delkndva:
   elseif erg% = 13
      a.name$ = name$ : a.tel$ = tel$
      append : giprint "Hinzugefügt"
      showknd:
   endif
endp

proc wahla%:
   local erg%
   use a
   erg% = ediknd%:("Kundedaten ändern")
   if erg% = 0 or erg%=27
      delkndva:
   elseif erg% = 13
      a.name$ = name$ : a.tel$ = tel$
      update : giprint "Gändert"
      last : showknd:
   endif
endp

proc ediknd%:(title$)
   local erg%
   do
      dinit title$
      dedit name$,"Kundenname:"
      dedit tel$,"Telefonnummer:"
      dbuttons "Nicht speichern",27,"Speichern",13
      erg% = dialog
   until erg% = 0 or erg%=13
   return erg%
endp

proc wahll%:
   local erg%
   use a
   if count > 0
      dinit "Kunden löschen"
      dtext "","Wirklich löschen"
      dbuttons "Ja",%j,"Nein",%n
      erg% = dialog
      if erg%=%n
         return
      elseif erg% = %j
         erase : position 1 : showknd:
      endif
   endif
endp

proc wahle%:
   use a : close : stop
endp

proc delkndva:
   name$ = "" : tel$ = ""
endp

proc showknd:
   local c%
   cls : db2knd:
   print "K U N D E N D A T E N"
   print "-----------"
   print "Kundenname: "+chr$(9)+name$
   print "   Telefon: "+chr$(9)+tel$
   do
      print
      c% = c% + 1
   until c% = 9
   if count <> 0
      print "Datensatz ";pos;"/";count
   else
      print "Datensatz 0/0"
   endif
   print
   print "<-" + " Zurück/Vor " + "->" + " oder Menü-Taste"
   gborder 0
endp

proc db2knd:
   use a : name$ = a.name$ : tel$ = a.tel$
endp

proc rollen:(keycode%)
   if count > 1
      if taste% = 259
         if pos = 1
            giprint "1. Datensatz"
         else
            back : showknd:
         endif
      elseif taste% = 258
         if pos = count
            giprint "Letzter Datensatz"
         else
            next : showknd:
         endif
      endif
   endif
endp

PROC wahls%:
   REM Eintrag Suchen
   LOCAL f%, erg%, n%
   IF COUNT   REM es gibt Einträge!
      delkndva:
      IF ediSuch%:("Suche nach ..")
         FIRST
         CLS
         PRINT "Index-Name-Telefon:" : PRINT
         DO
            f%=FIND(name$)
            IF f%
               PRINT f%," - ";a.name$;" - ",a.tel$
               n%=n% + 1
               IF n%=10*(n%/10)
                  PRINT : PRINT "Taste für weiter!"
                  GET : CLS
                  PRINT "Index-Name-Telefon:" : PRINT
               ENDIF
            ENDIF
            NEXT
         UNTIL EOF
         IF n%=0
            PRINT " .. nichts gefunden!"
         ENDIF
         PRINT : PRINT "Suche beendet. Taste drücken."
         GET
      ELSE
         REM Abbruch der Suche ohne Meldung
      ENDIF
   ELSE
      CLS
      PRINT "Keine Daten! Taste."
      GET
   ENDIF
   FIRST
   showknd:
ENDP

PROC ediSuch%:(title$)
   name$="*"
   dINIT title$
   dEDIT name$,"Kundenname:"
   dBUTTONS "Abbruch",27,"Fertig",13
   RETURN DIALOG
ENDP

PROC wahlg%:
   REM Gehe zu (Datensatz)
   LOCAL f%, ds&, n%
   IF COUNT
      ds&=ediGoto&:("Gehe zu Datensatz")
      POSITION ds&
   ELSE
      CLS : PRINT "Kein Daten! Taste." : GET
   ENDIF
   showknd:
ENDP

PROC ediGoto&:(title$)
   REM Datensatznummer f. "wahlg%:" bereitstellen
   LOCAL eingabe&
   eingabe&=1
   dINIT title$
   dLONG eingabe&,"Datensatz-Nr.?",1,COUNT
   dBUTTONS "Fertig",13
   DIALOG
   RETURN eingabe&
ENDP